cgen: fix default value in if/else or block (fix #26002) (#26020)

Author: dy-tea

vlib/v/gen/c/if.v

@@ -200,8 +200,13 @@ fn (mut g Gen) if_expr(node ast.IfExpr) {
 	mut exit_label := ''
 	if needs_tmp_var {
 		exit_label = g.new_tmp_var()
-		mut styp := g.styp(node.typ)
-		if g.inside_if_option || node.typ.has_flag(.option) {
+		node_typ := if g.inside_or_block {
+			node.typ.clear_option_and_result()
+		} else {
+			node.typ
+		}
+		mut styp := g.styp(node_typ)
+		if (g.inside_if_option || node_typ.has_flag(.option)) && !g.inside_or_block {
 			raw_state = g.inside_if_option
 			if node.typ != ast.void_type {
 				g.last_if_option_type = node.typ
@@ -214,15 +219,15 @@ fn (mut g Gen) if_expr(node ast.IfExpr) {
 			}
 			g.inside_if_option = true
 			styp = styp.replace('*', '_ptr')
-		} else if node.typ.has_flag(.result) {
+		} else if node_typ.has_flag(.result) && !g.inside_or_block {
 			raw_state = g.inside_if_result
 			defer(fn) {
 				g.inside_if_result = raw_state
 			}
 			g.inside_if_result = true
 			styp = styp.replace('*', '_ptr')
 		} else {
-			g.last_if_option_type = node.typ
+			g.last_if_option_type = node_typ
 			defer(fn) {
 				g.last_if_option_type = tmp_if_option_type
 			}

vlib/v/tests/if_expr_in_or_block_test.v

@@ -0,0 +1,105 @@
+fn foo(a int) !int {
+	if a < 0 {
+		return error('foo')
+	}
+	return a
+}
+
+fn bar(a int) !int {
+	return foo(a) or {
+		if a < 0 {
+			-1
+		} else {
+			return error('bar')
+		}
+	}
+}
+
+fn baz(a int) !int {
+	return foo(a) or {
+		if a < 0 {
+			-1
+		} else {
+			-2
+		}
+	}
+}
+
+fn qux(a int) ?int {
+	if a < 0 {
+		return none
+	}
+	return a
+}
+
+fn quux(a int) ?int {
+	return qux(a) or {
+		if a < 0 {
+			-1
+		} else {
+			return none
+		}
+	}
+}
+
+fn test_if_expr_in_result_or_block_with_return() {
+	assert bar(0)! == 0
+	assert bar(-1)! == -1
+	assert bar(1)! == 1
+}
+
+fn test_if_expr_in_result_or_block_simple() {
+	assert baz(0)! == 0
+	assert baz(-1)! == -1
+	assert baz(1)! == 1
+}
+
+fn test_if_expr_in_option_or_block_with_return() {
+	assert quux(0)? == 0
+	assert quux(-1)? == -1
+	assert quux(1)? == 1
+}
+
+fn test_nested_if_in_or_block() {
+	get_val := fn (x int) !int {
+		if x < 0 {
+			return error('negative')
+		}
+		return x * 2
+	}
+	result := get_val(-5) or {
+		if true {
+			if false {
+				100
+			} else {
+				-10
+			}
+		} else {
+			200
+		}
+	}
+	assert result == -10
+}
+
+fn test_if_expr_with_multiple_branches_in_or_block() {
+	compute := fn (x int) !int {
+		if x == 0 {
+			return error('zero')
+		}
+		return x
+	}
+	val := compute(0) or {
+		match err.msg() {
+			'zero' {
+				1
+			}
+			'negative' {
+				2
+			}
+			else {
+				3
+			}
+		}
+	}
+	assert val == 1
+}