v2: lots of arm64/ssa fixes; make array_test and string_test pass with arm64

Author: medvednikov

cmd/v2/test_all.sh

@@ -3,34 +3,53 @@ set -euo pipefail
 
 cd "$(dirname "$0")"
 
-echo "=== 1/7: Self-host test ==="
+echo "=== 1/9: Self-host test ==="
 bash test_v2_self.sh
 
 echo ""
-echo "=== 2/7: Rebuild v2 and run builtin test files ==="
+echo "=== 2/9: Rebuild v2 and run builtin test files ==="
+rm -rf /tmp/v2_cleanc_obj_cache
 v self && v -o v2 v2.v
 ./v2 ../../vlib/builtin/array_test.v
 ./v2 ../../vlib/builtin/string_test.v
 ./v2 ../../vlib/builtin/map_test.v
 
 echo ""
-echo "=== 3/7: Math test ==="
+echo "=== 3/9: Builtin test files (arm64) ==="
+./v2 -backend arm64 ../../vlib/builtin/array_test.v
+./v2 -backend arm64 ../../vlib/builtin/string_test.v
+
+echo ""
+echo "=== 4/9: Math test ==="
 ./v2 ../../vlib/math/math_test.v
 
 echo ""
-echo "=== 4/7: SSA backends test (arm64) ==="
+echo "=== 5/9: Sumtype tests ==="
+./v2 test_sumtype.v
+./v2 test_sumtype2.v
+./v2 test_sumtype3.v
+./v2 test_sumtype4.v
+./v2 test_sumtype_pos.v
+./v2 test_sumtype_data.v
+./v2 test_sumtype_ifexpr.v
+./v2 test_sumtype_nested.v
+./v2 test_sumtype_many.v
+./v2 test_sumtype_global.v
+
+echo ""
+echo "=== 6/9: SSA backends test (arm64) ==="
 v -gc none run test_ssa_backends.v arm64
 
 echo ""
-echo "=== 5/7: SSA backends test (cleanc) ==="
+echo "=== 7/9: SSA backends test (cleanc) ==="
 v -gc none run test_ssa_backends.v cleanc
 
 echo ""
-echo "=== 6/7: Transformer test ==="
+echo "=== 8/9: Transformer test ==="
 v ../../vlib/v2/transformer/transformer_v2_darwin_test.v
 
 echo ""
-echo "=== 7/7: Cleanc runtime tests ==="
+echo "=== 9/9: Cleanc runtime tests ==="
 v -gc none run ../../vlib/v2/gen/cleanc/tests/run_tests.v
 
 echo ""

cmd/v2/test_sumtype.v

@@ -0,0 +1,28 @@
+type Animal = Cat | Dog
+
+struct Cat {
+	name string
+}
+
+struct Dog {
+	name string
+	age  int
+}
+
+fn make_animal() Animal {
+	return Animal(Cat{
+		name: 'whiskers'
+	})
+}
+
+fn main() {
+	a := make_animal()
+	match a {
+		Cat {
+			println(a.name)
+		}
+		Dog {
+			println(a.name)
+		}
+	}
+}

cmd/v2/test_sumtype2.v

@@ -0,0 +1,50 @@
+struct Cat {
+	name string
+}
+
+struct Dog {
+	name string
+	age  int
+}
+
+struct Bird {
+	name    string
+	can_fly bool
+}
+
+type Animal = Bird | Cat | Dog
+
+fn make_cat() Animal {
+	return Animal(Cat{
+		name: 'whiskers'
+	})
+}
+
+fn make_bird() Animal {
+	return Animal(Bird{
+		name:    'tweety'
+		can_fly: true
+	})
+}
+
+fn indirect() Animal {
+	a := make_cat()
+	return a
+}
+
+fn get_name(a Animal) string {
+	match a {
+		Cat { return a.name }
+		Dog { return a.name }
+		Bird { return a.name }
+	}
+}
+
+fn main() {
+	a := make_cat()
+	b := make_bird()
+	c := indirect()
+	println(get_name(a))
+	println(get_name(b))
+	println(get_name(c))
+}

cmd/v2/test_sumtype3.v

@@ -0,0 +1,44 @@
+struct Cat {
+	name string
+}
+
+struct Dog {
+	name string
+	age  int
+}
+
+struct Bird {
+	name    string
+	can_fly bool
+}
+
+type Animal = Bird | Cat | Dog
+
+fn make_conditional(which int) Animal {
+	result := if which == 0 {
+		Animal(Cat{
+			name: 'whiskers'
+		})
+	} else {
+		Animal(Bird{
+			name:    'tweety'
+			can_fly: true
+		})
+	}
+	return result
+}
+
+fn get_name(a Animal) string {
+	match a {
+		Cat { return a.name }
+		Dog { return a.name }
+		Bird { return a.name }
+	}
+}
+
+fn main() {
+	a := make_conditional(0)
+	b := make_conditional(1)
+	println(get_name(a))
+	println(get_name(b))
+}

cmd/v2/test_sumtype4.v

@@ -0,0 +1,38 @@
+struct Ident {
+	name string
+	line int
+	col  int
+}
+
+struct Literal {
+	value string
+}
+
+type Expr = Ident | Literal
+
+fn make_ident() Ident {
+	return Ident{
+		name: 'foo'
+		line: 42
+		col:  10
+	}
+}
+
+fn wrap_expr() Expr {
+	i := make_ident()
+	return i
+}
+
+fn main() {
+	e := wrap_expr()
+	match e {
+		Ident {
+			println(e.name)
+			println(e.line)
+			println(e.col)
+		}
+		Literal {
+			println(e.value)
+		}
+	}
+}

cmd/v2/test_sumtype_data.v

@@ -0,0 +1,40 @@
+struct Pos {
+	x int
+	y int
+}
+
+struct Ident {
+	pos  Pos
+	name string
+}
+
+struct Lit {
+	pos Pos
+	val int
+}
+
+type Expr = Ident | Lit
+
+fn (e Expr) get_pos() Pos {
+	return match e {
+		Ident { e.pos }
+		Lit { e.pos }
+	}
+}
+
+fn make_ident() Expr {
+	return Expr(Ident{
+		pos:  Pos{
+			x: 10
+			y: 20
+		}
+		name: 'hello'
+	})
+}
+
+fn main() {
+	e := make_ident()
+	p := e.get_pos()
+	println(p.x.str())
+	println(p.y.str())
+}

cmd/v2/test_sumtype_global.v

@@ -0,0 +1,71 @@
+struct Pos {
+	x int
+	y int
+}
+
+struct Ident {
+	pos  Pos
+	name string
+}
+
+struct EmptyExpr {
+	dummy u8
+}
+
+type Expr = EmptyExpr | Ident
+
+const empty_expr = Expr(EmptyExpr{})
+
+fn (e Expr) get_pos() Pos {
+	return match e {
+		Ident { e.pos }
+		EmptyExpr { Pos{} }
+	}
+}
+
+fn parse_expr() Expr {
+	return Expr(Ident{
+		pos:  Pos{
+			x: 42
+			y: 99
+		}
+		name: 'macos'
+	})
+}
+
+struct Parser {
+mut:
+	tok      int
+	comptime bool
+}
+
+fn (mut p Parser) expr_or_type() Expr {
+	return Expr(Ident{
+		pos:  Pos{
+			x: 77
+			y: 88
+		}
+		name: 'linux'
+	})
+}
+
+fn (mut p Parser) if_expr(is_comptime bool) {
+	// Exact pattern from the real parser
+	mut cond := if p.tok == 42 {
+		empty_expr // global constant
+	} else {
+		if is_comptime { p.expr_or_type() } else { p.expr_or_type() }
+	}
+	// This line is what crashes in v3
+	guard_pos := cond.get_pos()
+	println(guard_pos.x.str())
+	println(guard_pos.y.str())
+}
+
+fn main() {
+	mut parser := Parser{
+		tok:      99
+		comptime: true
+	}
+	parser.if_expr(true) // should print 77, 88
+}

cmd/v2/test_sumtype_ifexpr.v

@@ -0,0 +1,48 @@
+struct Pos {
+	x int
+	y int
+}
+
+struct Ident {
+	pos  Pos
+	name string
+}
+
+struct EmptyExpr {
+	dummy u8
+}
+
+type Expr = EmptyExpr | Ident
+
+fn (e Expr) get_pos() Pos {
+	return match e {
+		Ident { e.pos }
+		EmptyExpr { Pos{} }
+	}
+}
+
+fn parse_expr() Expr {
+	return Expr(Ident{
+		pos:  Pos{
+			x: 42
+			y: 99
+		}
+		name: 'macos'
+	})
+}
+
+fn test_if_expr(is_lcbr bool) {
+	mut cond := if is_lcbr {
+		Expr(EmptyExpr{})
+	} else {
+		parse_expr()
+	}
+	p := cond.get_pos()
+	println(p.x.str())
+	println(p.y.str())
+}
+
+fn main() {
+	test_if_expr(false) // should print 42, 99
+	test_if_expr(true) // should print 0, 0
+}