TikZ: Generate a pixelated (Minecraft-style) circle by filling unit grid squares [duplicate]

While you are waiting for TikZ-help, here is an effort in Metapost for comparison.

You need to compile this with lualatex:

\documentclass[border=5mm]{standalone}
\usepackage{luamplib}
\begin{document}
\mplibtextextlabel{enable}
\begin{mplibcode}
vardef block_circle(expr r, s) = image(
  save block, b, n, w; 
  path block; block = unitsquare shifted -(.5,.5) scaled s;
  numeric n; n = round(r/s) + 1;
  for x = -n upto n:
    for y = -n upto n:
      pair w; w = (x,y) scaled s;
      if abs w < r:
        path b; b = block scaled 0.9 rotated 3/4 normaldeviate shifted w;
        if xpart (fullcircle scaled 2r intersectiontimes b) < 0:
          fill b withcolor (uniformdeviate 1, uniformdeviate 3/4, uniformdeviate 1/2);
        fi
        draw b if n > 10: withpen pencircle scaled 1/4 fi;
      fi
    endfor
  endfor
) enddef;

beginfig(1);
  for i = 1 upto 4:
    draw block_circle(64, 5i) shifted (144i, 0);
    draw fullcircle scaled 128 shifted (144i, 0) withcolor red;
  endfor
endfig;
\end{mplibcode}
\end{document}

There are a couple of things to adapt / fiddle with:

• You might not want the fancy decoration on each square, so you could change the path b; line to

    path b; b = block shifted w;
  

• You might want to include squares that touch the circle; if so you can get rid of the inner if so that it does not bother with the intersection check.

• You might want to exclude squares that touch the circle; if so you should move the draw b line inside the inner if.