v.vmod: add encoder/1 too (#24034)

Author: gechandesu

vlib/v/vmod/encoder.v

@@ -0,0 +1,61 @@
+module vmod
+
+import strings
+
+fn quote(input string) string {
+	if input.contains("'") {
+		return '"' + input + '"'
+	}
+	return "'" + input + "'"
+}
+
+fn encode_array(mut b strings.Builder, input []string) {
+	if input.join('').len > 60 {
+		b.writeln('[')
+		for item in input {
+			b.write_string('\t\t')
+			b.write_string(quote(item))
+			b.writeln(',')
+		}
+		b.writeln('\t]')
+	} else {
+		mut quoted := []string{}
+		for item in input {
+			quoted << quote(item)
+		}
+		b.write_string('[')
+		b.write_string(quoted.join(', '))
+		b.writeln(']')
+	}
+}
+
+pub fn encode(manifest Manifest) string {
+	mut b := strings.new_builder(512)
+	b.writeln('Module {')
+	b.write_string('\tname: ')
+	b.writeln(quote(manifest.name))
+	b.write_string('\tdescription: ')
+	b.writeln(quote(manifest.description))
+	b.write_string('\tversion: ')
+	b.writeln(quote(manifest.version))
+	b.write_string('\tlicense: ')
+	b.writeln(quote(manifest.license))
+	if manifest.repo_url != '' {
+		b.write_string('\trepo_url: ')
+		b.writeln(quote(manifest.repo_url))
+	}
+	if manifest.author != '' {
+		b.write_string('\author: ')
+		b.writeln(quote(manifest.author))
+	}
+	b.write_string('\tdependencies: ')
+	encode_array(mut b, manifest.dependencies)
+	for key, values in manifest.unknown {
+		b.write_string('\t')
+		b.write_string(key)
+		b.write_string(': ')
+		encode_array(mut b, values)
+	}
+	b.write_string('}')
+	return b.str()
+}

vlib/v/vmod/encoder_test.v

@@ -0,0 +1,65 @@
+import v.vmod
+
+const mf_no_deps = "Module {
+	name: 'V'
+	description: 'The V programming language.'
+	version: '0.4.10'
+	license: 'MIT'
+	repo_url: 'https://github.com/vlang/v'
+	dependencies: []
+}"
+
+fn test_encode_vmod_with_no_deps() {
+	mf := vmod.decode(mf_no_deps)!
+	assert vmod.encode(mf) == mf_no_deps
+}
+
+const mf_with_deps_1 = "Module {
+	name: 'V'
+	description: 'The V programming language.'
+	version: '0.4.10'
+	license: 'MIT'
+	repo_url: 'https://github.com/vlang/v'
+	dependencies: ['hello', 'world']
+}"
+
+const mf_with_deps_2 = 'Module {
+	name: \'V\'
+	description: "The V\' programming language."
+	version: \'0.4.10\'
+	license: \'MIT\'
+	repo_url: \'https://github.com/vlang/v\'
+	dependencies: [
+		\'hello\',
+		\'world\',
+		\'fdsfgarhrhregwegewgeage\',
+		\'geageaegeggegagaghjuktktytrrtrehitroorekfwepokooe\',
+	]
+}'
+
+fn test_encode_vmod_with_multiple_deps() {
+	mf1 := vmod.decode(mf_with_deps_1)!
+	assert vmod.encode(mf1) == mf_with_deps_1
+	mf2 := vmod.decode(mf_with_deps_2)!
+	assert vmod.encode(mf2) == mf_with_deps_2
+}
+
+const mf_with_extra_fields = "Module {
+	name: 'V'
+	description: 'The V programming language.'
+	version: '0.4.10'
+	license: 'MIT'
+	repo_url: 'https://github.com/vlang/v'
+	dependencies: ['hello', 'world']
+	extra_a: ['a', 'b', 'c']
+	extra_b: [
+		'aaaaaaaaaaaaaaaaaaaaa',
+		'bbbbbbbbbbbbbbbbbbbbb',
+		'ccccccccccccccccccccc',
+	]
+}"
+
+fn test_encode_vmod_with_extra_fields() {
+	mf := vmod.decode(mf_with_extra_fields)!
+	assert vmod.encode(mf) == mf_with_extra_fields
+}

vlib/v/vmod/parser.v

@@ -22,12 +22,12 @@ enum TokenKind {
 pub struct Manifest {
 pub mut:
 	name         string
-	version      string
 	description  string
-	dependencies []string
+	version      string
 	license      string
 	repo_url     string
 	author       string
+	dependencies []string
 	unknown      map[string][]string
 }