Components All New MacOS Windows Linux iOS
Examples Mac & Win Server Client Guides Statistic FMM Blog Deprecated Old

FM.ExecuteFileSQLOnIdle

Executes a SQL command at idle time.

Component Version macOS Windows Linux Server iOS SDK
FM FMSQL 6.5 ✅ Yes ✅ Yes ✅ Yes ✅ Yes ✅ Yes
MBS( "FM.ExecuteFileSQLOnIdle"; SQL Statement; FileName { ; Column Delimiter; Record Delimiter; Params... } )   More

Parameters

Parameter Description Example Flags
SQL Statement the SQL statement
FileName The file name of the database.

Using a table in another database file may require you adding the other file as an external data source and adding the external table to your relationship graph to grant access.		 Get(FileName)
Column Delimiter Columns Separator.
Default is tab character, which has unicode code point 9.
You can pass delimiter as text (one character only) or as unicode code point (as number).		 9 Optional
Record Delimiter Record Separator.
Default is return character, which has unicode code point 13.
You can pass delimiter as text (one character only) or as unicode code point (as number).		 13 Optional
Params... Optional, pass here parameters. One parameter to this function for each parameter you want to pass to the SQL statement. 123 Optional

Result

Returns OK or error.

Description

Executes a SQL command at idle time.
This is similar to FM.ExecuteFileSQL, except that it waits until idle to execute..
You run a script pause after using this function to give it time to execute.
See the other function for more info.

Seems like on FileMaker 11 you get LastError 8310 if you use fields with underscore in the name. You avoid that by placing the field names in quotes.
Use FM.ExecuteSQL.LastErrorMessage and FM.ExecuteSQL.LastError to see error message.

You can do more schema changes via ODATA interface on FileMaker Server including changing or renaming fields.

Please notice that FM.ExecuteFileSQLOnIdle and FM.ExecuteFileSQL have the filename parameter on different positions.

This function takes variable number of parameters. Pass as much parameters as needed separated by the semicolon in FileMaker.
Please repeat Params parameter as often as you need.

Examples

Create a new text field in a table:

MBS("FM.ExecuteSQLOnIdle";"ALTER TABLE TestTable ADD MyField varchar")

Create in a script and check error:

# set command to run
Set Variable [ $r ; Value: MBS("FM.ExecuteFileSQLOnIdle"; "ALTER TABLE Kontakte ADD MyField varchar"; "Kontakte.fmp12") ]
# Make pause to run it
Pause/Resume Script [ Duration (seconds): ,1 ]
# Check error status
Set Variable [ $errorNumber ; Value: MBS( "FM.ExecuteSQL.LastError" ) ]
Set Variable [ $errorMessage ; Value: MBS( "FM.ExecuteSQL.LastErrorMessage" ) ]

Create a field:

Set Variable [ $r ; Value: MBS("FM.ExecuteFileSQLOnIdle";"ALTER TABLE TestTable ADD MyField varchar"; Get(FileName)) ]
Pause/Resume Script [ Duration (seconds): ,1 ]
If [ MBS("FM.ExecuteSQL.LastError") ≠ 0 ]
    Show Custom Dialog [ "Failed to add field" ; MBS("FM.ExecuteSQL.LastError") & ": " & MBS("FM.ExecuteSQL.LastErrorMessage") ]
Else
    Show Custom Dialog [ "Added field." ; "OK" ]
End If

Create a new text field in a table with variables for the names:

Set Variable [ $TableName ; Value: "TestTable" ]
Set Variable [ $FieldName ; Value: "MyField" ]
Set Variable [ $FieldType ; Value: "VARCHAR" ]

Set Variable [ $r ; Value: MBS("FM.ExecuteFileSQLOnIdle";"ALTER TABLE \"" & $TableName & "\" ADD \"" & $FieldName & "\" " & $FieldType & " " ; Get(FileName)) ]
Pause/Resume Script [ Duration (seconds): ,1 ]
If [ MBS("FM.ExecuteSQL.LastError") ≠ 0 ]
    Show Custom Dialog [ "Error adding field" ; MBS("FM.ExecuteSQL.LastError") & ": " & MBS("FM.ExecuteSQL.LastErrorMessage") ]
Else
    Show Custom Dialog [ "Added field" ; "OK" ]
End If

Create a table:

Set Variable [ $r ; Value: MBS("FM.ExecuteFileSQLOnIdle";"CREATE TABLE \"TestTable\" (ID INT PRIMARY KEY, MyTextField VARCHAR, MyNumberField DECIMAL)"; Get(FileName)) ]
# for details see fm16_sql_reference.pdf (or newer) from Claris Inc.

Rename field:

MBS("FM.ExecuteFileSQLOnIdle"; "ALTER TABLE Kontakte RENAME COLUMN Feld TO Feld2"; Get(FileName))
// Needs FileMaker 22.0 or newer

Create two tables with relationship:

Set Variable [ $r ; Value: MBS("FM.ExecuteFileSQLonIdle"; "CREATE TABLE Departments ( DepartmentID int PRIMARY KEY, Name varchar(100) NOT NULL )"; ""; "") ]
Pause/Resume Script [ Duration (seconds): ,1 ]
If [ MBS("FM.ExecuteSQL.LastError") ]
    Show Custom Dialog [ "SQL failed" ; MBS("FM.ExecuteSQL.LastErrorMessage") ]
End If
#
Set Variable [ $r ; Value: MBS("FM.ExecuteFileSQLonIdle"; "CREATE TABLE Employees ( EmployeeID int PRIMARY KEY, Name varchar(100) NOT NULL, DepartmentID int FOREIGN KEY REFERENCES Departments(DepartmentID) )"; ""; "") ]
Pause/Resume Script [ Duration (seconds): ,1 ]
If [ MBS("FM.ExecuteSQL.LastError") ]
    Show Custom Dialog [ "SQL failed" ; MBS("FM.ExecuteSQL.LastErrorMessage") ]
End If
# Requires FileMaker 2026 or newer.

Add a new field with relationship:

Set Variable [ $r ; Value: MBS("FM.ExecuteFileSQLonIdle"; "ALTER TABLE Assets ADD DepartmentID int FOREIGN KEY REFERENCES Departments(DepartmentID)"; ""; "") ]
Pause/Resume Script [ Duration (seconds): ,1 ]
If [ MBS("FM.ExecuteSQL.LastError") ]
    Show Custom Dialog [ "SQL failed" ; MBS("FM.ExecuteSQL.LastErrorMessage") ]
End If
# Requires FileMaker 2026 or newer.

See also

Release notes

Blog Entries

This function checks for a license.

Created 16th October 2016, last changed 21st May 2026


FM.ExecuteFileSQL - FM.ExecuteFileSQLValue