Invocation fails if %0 is "prog" instead of "path\to\prog" and prog was quoted when invoked

[staticshock]

Try "jshint" --version in cmd.exe, for instance. It won't work because it seems that cmd.exe doesn't set %~dp0 correctly when a batch script is quoted during invocation.

[staticshock]

This work-around works for me:

@ECHO.%0 | FINDSTR /C:\ /C:/ >NUL && (
    SET dir=%~dp0
) || (
    FOR /F %%i IN ('where %0') DO @SET dir=%%~dpi
)
@IF EXIST "%dir%\node.exe" (
  "%dir%\node.exe" "%dir%\node_modules\jshint\bin\jshint" %*
) ELSE (
  @SETLOCAL
  @SET PATHEXT=%PATHEXT:;.JS;=;%
  node "%dir%\node_modules\jshint\bin\jshint" %*
)

To summarize:

• Check if %0 contains slashes or backslashes.
  • If it does, use %~dp0 as is, since it'll be set correctly in this case, even when "path\to\prog" is quoted.
  • Otherwise, use the output of where %0. This works poorly if %0 is a path, but works reasonably well if %0 is just an executable name, such as "jshint" or "jshint.cmd", quoted or unquoted. (Minor note: where %0 may return multiple hits, in which case the last hit is used, since there's no break in the loop.)
• The rest of the script remains as is, only with %dir% instead of %~dp0.

[staticshock]

For context, this issue is causing https://secure.phabricator.com/T6966

[rprichard]

FWIW: As another idea for a workaround, it looks like %~dp0 has the expected path after calling a subroutine in a batch file, e.g.:

@echo off
setlocal
call :find_bin
echo Do something with %_BIN_DIR%...
exit /b

:find_bin
set _BIN_DIR=%~dp0
exit /b

More details here: android/ndk#616 (comment). It doesn't work with Wine CMD, but that's probably easy to work around (or fix in Wine).

[isaacs]

I implemented the "subroutine workaround" in the latest release of cmd-shim. It's a breaking change because it required an update to read-cmd-shim, which looked for %~dp0 specifically in a file to find its target.

This will be in npm v6.11.0. Thanks, everyone!